TM/gnuplot/data.png.gpi

# Inspired by http://youinfinitesnake.blogspot.ch/2011/02/attractive-scientific-plots-with.html
# and http://www.gnuplotting.org/attractive-plots/

set terminal pngcairo size 960,1360 enhanced font 'Verdana,9'
set output 'data.png'

# define axis
# remove border on top and right and set color to gray
set style line 11 lc rgb '#808080' lt 1
set border 3 back ls 11
set tics nomirror
# define grid
set style line 12 lc rgb '#808080' lt 0 lw 1
set grid back ls 12

set style line 1 linetype 1
set style line 2 linetype 1
set style line 3 linetype 1
set style line 4 linetype 1
set style line 1 linetype rgb '#A00000' linewidth 2 pointtype 7
set style line 2 linetype rgb '#00A000' linewidth 2 pointtype 9
set style line 3 linetype rgb '#5060D0' linewidth 2 pointtype 5
set style line 4 linetype rgb '#F25900' linewidth 2 pointtype 13

set size 1,1
set origin 0,0

set xlabel 'Temps [hhmm]'
set xdata time                  # the x-axis is time
set format x '%H%M'             # display as time
set timefmt '%Y-%m-%d %H:%M:%S' # but read in as datetime

set multiplot

set size 1,0.25
set origin 0,0.75
set ylabel 'Température'
plot 'DATA.TSV' using 1:3 title 'T [°C]' with linespoints linestyle 1

set size 1,0.25
set origin 0,0.5
set ylabel 'Pression'
plot 'DATA.TSV' using 1:($4/100) title 'P [hPa]' with linespoints linestyle 2

set size 1,0.25
set origin 0,0.25
set ylabel 'Humidité'
plot 'DATA.TSV' using 1:6 title 'Hr [%]' with linespoints linestyle 3

set size 1,0.25
set origin 0,0
set ylabel 'Luminosité'
plot 'DATA.TSV' using 1:7 title 'Lx [Lux]' with linespoints linestyle 4

unset multiplot
reset

set output