N4th4/TM
1
0
Fork 0
Code Issues Pull Requests Releases Wiki Activity

Add presentation

Browse Source
This commit is contained in:
Nathanaël Restori
2012-11-23 22:11:35 +01:00
parent 8a669ad03c
commit 5d189218ac
14 changed files with 178852 additions and 20 deletions
Download Patch File Download Diff File Expand all files Collapse all files

52
gnuplot/data-pres.epslatex.gpi Normal file
View File

@@ -0,0 +1,52 @@
# Inspired by http://youinfinitesnake.blogspot.ch/2011/02/attractive-scientific-plots-with.html
# and http://www.gnuplotting.org/attractive-plots/
# define axis
# remove border on top and right and set color to gray
set style line 11 lc rgb '#808080' lt 1
set border 3 back ls 11
set tics nomirror
# define grid
set style line 12 lc rgb '#808080' lt 0 lw 1
set grid back ls 12
set style line 1 linetype 1
set style line 2 linetype 1
set style line 3 linetype 1
set style line 4 linetype 1
set style line 1 linetype rgb '#A00000' linewidth 2 pointtype 7
set style line 2 linetype rgb '#00A000' linewidth 2 pointtype 9
set style line 3 linetype rgb '#5060D0' linewidth 2 pointtype 5
set style line 4 linetype rgb '#F25900' linewidth 2 pointtype 13
set size 1,1
set origin 0,0
set terminal epslatex size 4.6,2.9 color colortext 'phv,9' header '\definecolor{t}{rgb}{0.5,0.5,0.5}'
set format '\color{t}$%g$'
set output 'data-pres-t.tex'
set xlabel 'Temps [hh]'
set xdata time # the x-axis is time
set format x '%H' # display as time
set timefmt '%Y-%m-%d %H:%M:%S' # but read in as datetime
set ylabel 'Température'
plot 'DATA.TSV' using 1:3 title 'T [°C]' with linespoints linestyle 1
set output 'data-pres-p.tex'
set ylabel 'Pression'
plot 'DATA.TSV' using 1:($4/100) title 'P [hPa]' with linespoints linestyle 2
set output 'data-pres-h.tex'
set ylabel 'Humidité'
plot 'DATA.TSV' using 1:6 title 'Hr [\%]' with linespoints linestyle 3
set output 'data-pres-l.tex'
set ylabel 'Luminosité'
plot 'DATA.TSV' using 1:7 title 'Lx [Lux]' with linespoints linestyle 4
reset
set output